Fehler bei set scope to?

[Werner_Bayern]

Servus,

ich finde einfach den Fehler nicht. Hab eine artikel.dbf und entsprechende Indexe dazu.

Code: Alles auswählen

index on upper(text) to text.ntx
index on upper(match) to match.ntx

So, nun die Eingrenzung mittels scope:

Code: Alles auswählen

  case nAuswahl == 3   // Text
      set index to text.ntx
      if empty(xBis)
         xBis := "ZZZZZZZZZ"
      endif
      set scope to xVon, xBis

   case nAuswahl == 6   // Matchcode
      set index to match.ntx
      if empty(xBis)
         xBis := "ZZZZZZZZZ"
      endif
      set scope to xVon, xBis

Text geht, Matchcode-Feld nicht. Text ist C 40, Match ist C 15. Tausche ich auf

set index to text.ntx

bei nAuswahl == 6, stimmt der scope sauber mittels Text. Indexe sind neu erzeugt, die passen, mit dbu wird die dbf sauber angezeigt.
xVon und xBis sind in beiden Fällen identisch belegt mit "A" und "L", ohne Leerzeichen. Bei Matchcode zeigt er mir jedoch immer nur die Einträge mit "A" an.

Sogar

Code: Alles auswählen

set scope to "A", "L"

zeigt bei Matchcode nur "A" an!

Warum

[Tom]

Ich sehe keinen Fehler, SET SCOPE funktioniert so bei Indexen auf Zeichenfeldern, ich hab's gerade ausprobiert, obwohl ich lieber mit den Funktions-Äquivalenten arbeite. Auch SET EXACT hat keinen Einfluss. Deshalb vermute ich einen inhaltlichen Fehler im Feld "MATCH". Führende Leerzeichen? Doch kein aktueller Index? Irgendwas in der Art? Welche Reihenfolge siehst Du, wenn Du die Tabelle mit dem MATCH-Index in DBU öffnest?

Gäbe es einen Fehler bei SET SCOPE, würdest Du den auch beim Scopen auf "TEXT" sehen, siehst Du aber nicht. Also ist irgendwas im Code oder in der Tabelle verhapelt.

[Werner_Bayern]

Deshalb vermute ich einen inhaltlichen Fehler im Feld "MATCH". Führende Leerzeichen? Doch kein aktueller Index? Irgendwas in der Art? Welche Reihenfolge siehst Du, wenn Du die Tabelle mit dem MATCH-Index in DBU öffnest?

Servus Tom,

danke. Aber nein, ich kann nichts finden, wie Du auch siehst, wird der index direkt vor dem scope-Befehl gesetzt und zum Testen hab ich auch schon unmittelbar davor neu indexieren lassen. Führende Leerzeichen? Grundsätzlich nein, im Feld Match steht selten was drin, aber wenn, dann ohne führende Leerzeichen.
Jetzt hab ich es gefunden, dank Deiner Antwort!!! Hab zum Test nochmal ein Feld geändert, wie der Zufall es wollte, stand in dem Feld match das Wort "Änderung". Habs ersetzt mit "W" und nochmal gescoped und siehe da, alles plötzlich da, nicht nur alle mit "A".
Es hat also was mit Umlaute zu tun!!!
Rekursiver Test: Steht "Änderung" wieder drin, wird wieder falsch gescoped.

[Tom]

Hallo, Werner.

Es hat also was mit Umlaute zu tun!!!

Mmh. Habe gerade mal eine Tabelle geöffnet, Index auf "Vorname", es gibt im Bereich O - P "Otto", "Ottokar", "Özlan", "Paul" und "Petra". SET SCOPE TO "O","P" zeigt auch exakt diese Datensätze an. Kein Abbruch beim "Ö".

ANSI <-> OEM?
SET CHARSET?
SET COLLATION?

[Werner_Bayern]

Das müsste genau meine Konstellation sein, bei der Du keine Probleme hast.

Character conversion: No Conversion (im VX eingestellt)
set charset to: ansi
Collation: nix

Tabelle ist mit clipper erstellt, also in oem. Wird auch von clipper aus benutzt.

DBU (Xbase++-Version) zeigt den Index korrekt an, in der Reihenfolge:

Code: Alles auswählen

Auto
Änderung
Blitz

[brandelh]

Klar kommt es auf Umlaute an "Ä" ist - ohne Änderung - deutlich größer als "Z" oder "z"
Wie hast du denn Indiziert ?

Code: Alles auswählen

SET COLLATION TO GERMAN

sollte zwar die Umlaute beim Sortieren und Indizieren ausschalten, aber sicher bin ich mir da nicht, DIN gibt es auch noch und SYSTEM unterscheidet nicht zwischen groß und klein.

[brandelh]

Gemischte Indexe mit Xbase++ und Clipper, das wird heiter
Bei Clipper gab es doch irgendwas mit DIN Sortierung, auf jeden Fall muss das genau stimmen, sonst gibt es Schrott.

Dass dein Programm in ANSI ist dürfte nicht stören, da das ja automatisch behandelt wird.

[brandelh]

Ich habe hier die deutsche Xbase++ Version installiert und in der DBESYS.PRG steht als Vorgabe:

Code: Alles auswählen

PROCEDURE dbeSys()
...
  /*
   *   Setzen der Sortierfolge und des Datumformates
   */
  SET COLLATION TO GERMAN
  SET DATE TO GERMAN

es könnte natürlich auch noch ein Fehler sein

[Werner_Bayern]

Servus Hubert,

im Clipper-Code hab ich reinen Standard, keine besondere Sortierung. Auch das DIN-Modul ist nicht mit eingebunden, sowas gabs mal, soweit ich weiß.
Der Index wird ja auch unter Xbase++ neu erzeugt, also mit allen Einstellungen aus Xbase. Zu der Zeit weiß der scope ja nichts, dass er falsch sortieren muss
Auch wenn Ä > Z, trotzdem müssen ja bei scope "A", "L" alle Einträge zwischen >= A und <= L kommen, bei mir kommen aber nur Einträge mit A und sonst nichts mehr. Lösche ich den einen Eintrag "Ä", kommen plötzlich alle korrekt von A-L.

[Tom]

Du wirst doch die Tabelle auch irgendwo in Deiner Applikation browsen (können). Was bzw. welche Reihenfolge siehst Du dort, wenn der Index auf "MATCH" steht?

SET COLLATION kann's eigentlich nicht sein, wenn DBU die Daten in der richtigen Reihenfolge anzeigt.

[brandelh]

Also bei meinen Tests scheint sich die Einstellung auf NTX Indexe nicht auszuwirken, und das ist auch LOGISCH,
denn sonst könnte man nicht gleichzeitig mit Clipper darauf zugreifen.
Somit muss man zwingend die Indizierung mit einer Funktion erledigen, die zuerst upper() und dann Ä -> A oder Ä -> AE erledigt.
Und genauso muss man auch den Skope einstellen.

set skope ist übrigens sehr scharf, beim ersten Satz, den er für größer hält wird sofort die Abfrage beendet.

ich würde einfach mal hingehen und eine sortierte liste in eine Textdatei ausgeben, dann siehst du wie er sortiert.
Auch ein dbseek( cTopWert ) // kleinerer Startwert und eine LIST REST ... kann dir zeigen was er anders versteht als du.

[Tom]

Es liegt am SET COLLATION.

Wenn ich meine Tabelle mit den Vornamen mit dem Standard (SET COLLATION TO GERMAN) und dem SCOPE TO "O", "P" browse, sehe ich auch Vornamen, die mit "Ö" anfangen. Jetzt schalte ich die Collation auf FRENCH. Die Anzeigereihenfolge bleibt gleich. Setze ich aber den Scope, werden nur Vornamen angezeigt, die mit "O" anfangen.

Also. Einfach SET COLLATION TO GERMAN in den Code, dann funzt es.

Mit Set(_SET_COLLATION) kann man sich übrigens die Sortierungstabelle anschauen.

[Werner_Bayern]

SET COLLATION TO GERMAN -> keine korrekte Anzeige
index neu -> keine kA
SET COLLATION TO FRENCH -> keine kA
index neu -> korrekte Anzeige, jedoch ohne Änderung (was ich verstehe)
SET COLLATION TO GERMAN -> korrekte A, immer noch ohne Änderung
index neu -> keine kA

[Werner_Bayern]

SET COLLATION TO SYSTEM, index neu -> korrekte Anzeige, aber ohne Änderung
SET COLLATION TO GERMAN, index neu, scope "Ä", "W" -> kein Satz wird angezeigt
scope "Ä", "Ä" -> der eine Satz wird korrekt angezeigt!
scope "Ä", "W" -> nichts wird angezeigt!

Hubert scheint Recht zu haben, der Scope steigt beim ersten Umlaut einfach aus. Ich denke, das wird ein Fall für den Alaska-Support, hab meine Subskription ja brav im November erneuert, da ja im ersten Quartal Arctica kommt.

[brandelh]

Jetzt hat es mich doch mal genauer interessiert und siehe da, meine Annahme bezüglich der Indexe war falsch.
Hier ist das Beispielprogramm:

Code: Alles auswählen

#include "Gra.ch"
#include "Xbp.ch"
#include "Common.ch"
#include "Inkey.ch"
procedure main()
   local aData, nAnz, x
   field name
   set alternate to TestScope.txt
   set alternate on
   aData := {"egon","hans","Hans","Ägar","Zensi","Ursel","Xaver","berd","Ürsül","Ursal","Heinrich"}
   nAnz  := len(aData)
   ? "Deutsche Version, unveränderte DBESYS.PRG"
   ? "erzeuge DBFNTX Datei mit unsortiertem Standardinhalt"
   ?
   dbcreate("test.dbf", { { "Name","C",20,0 } } )
   use test exclusive alias DB
   for x := 1 to nAnz
       append blank
       replace name with aData[x]
   next
   ? "unsortierte Liste"
   ?
   list all
   ?
   inkey(20)
   index on upper(name) to test
   ? "sortierte Liste"
   ?
   list all
   ?
   inkey(20)
   ? "set scope to 'H' ..."
   set scope to 'H'
   ?
   list all
   ?
   inkey(20)
   ? "set scope to 'Ä' ..."
   set scope to 'Ä'
   ?
   list all
   ?
   inkey(20)
   ? "set scope to 'A' ..."
   set scope to 'A'
   ?
   list all
   ?
   inkey(20)
   ? "set scope to 'A','Z' ..."
   set scope to 'A','Z'
   ?
   list all
   ?
   inkey(20)
   set alternate to
   memowrit("TestScope.txt", ConvToAnsiCP(memoread("TestScope.txt")))
return

Hier die Druckausgabe

Code: Alles auswählen

Deutsche Version, unveränderte DBESYS.PRG
erzeuge DBFNTX Datei mit unsortiertem Standardinhalt

unsortierte Liste

              1  egon                 
              2  hans                 
              3  Hans                 
              4  Ägar                 
              5  Zensi                
              6  Ursel                
              7  Xaver                
              8  berd                 
              9  Ürsül                
             10  Ursal                
             11  Heinrich             

sortierte Liste

              4  Ägar                 
              8  berd                 
              1  egon                 
              2  hans                 
              3  Hans                 
             11  Heinrich             
             10  Ursal                
              6  Ursel                
              9  Ürsül                
              7  Xaver                
              5  Zensi                

set scope to 'H' ...

              2  hans                 
              3  Hans                 
             11  Heinrich             

set scope to 'Ä' ...

              4  Ägar                 

set scope to 'A' ...


set scope to 'A','Z' ...

              4  Ägar                 
              8  berd                 
              1  egon                 
              2  hans                 
              3  Hans                 
             11  Heinrich             
             10  Ursal                
              6  Ursel                
              9  Ürsül                
              7  Xaver                
              5  Zensi                

und nochmals gezippt zum selbst probieren. Jetzt fällt mir auch wieder ein, warum ich die DIN Sortierung bei Clipper nie verwendet habe.
Wenn ich (bzw. meine Anwender) nach 'A' suche möchte ich auch die 'Ä' finden, wenn ich nach 'Ä' suche, auch 'A' und 'AE' ...

[AUGE_OHR]

hi,

sortierte Liste

4 Ägar

set scope to 'Ä' ...

4 Ägar

set scope to 'A' ...

nix ...

füge mal "albert" dazu.

4 albert
5 ägar

das wäre also noch "richtig".. aber ein "A" ist nun mal kein "Ä" also musst du den Scope so setzten:

Code: Alles auswählen

   ? "set scope to 'Ä' ..."
  set scope to "Ä"

   ? "set scope to 'A' ..."
*   set scope to 'A'
   SET SCOPETOP TO    "A"
   SET SCOPEBOTTOM TO "Ä"

und dann funktioniert es auch mit "Ä" dito das selbe mit O/Ö und U/Ü

[brandelh]

Hi Jimmy,

das ist viel zu umständlich, wenn man "A" von "Ä" (es gibt ja noch andere Sonderzeichen) trennen will, kann man es so lassen.
Ansonsten ist es viel einfacher und auch sicherer den Index per Funktion von Sonderzeichen zu eliminieren.
Am schnellsten wäre ein eigenes Indexfeld, das genau den übersetzten Indexausdruck hat und immer ohne Funktion indiziert einwandfrei funktioniert.

[UliTs]

Hi Jimmy,
das ist viel zu umständlich, wenn man "A" von "Ä" (es gibt ja noch andere Sonderzeichen) trennen will, kann man es so lassen.
...

Und ausserdem ist es je nach Einstellung auch falsch!
Uli

[Werner_Bayern]

Danke euch!

Hab jetzt nochmal selber umfangreich getestet, fügt mal folgende Zeile in euren Quelltext:

Code: Alles auswählen

 set charset to ansi

Das ist bei mir auch nötig, damit Umlaute im Programm (bei VX 2.0 als IDE und No Conversion) richtig dargestellt werden. Dann kann das Verhalten so nachvollzogen werden. Anbei ein komplettes Testprogramm.

[brandelh]

Wenn ich nicht gerade ein CMD Programm zum einfachen Test gemacht hätte, hätte ich auch auf ANSI umgestellt.
Wenn ich deine Datei nach OEM konvertiere (ich nutze ja kein VX) und charset auf OEM setze, dann funktioniert es richtig.

Ich denke, das ist ein klarer PDR !

Nach dem Anspruch von Alaska müsste die ANSI <=> OEM Konvertierung automatisch und richtig erfolgen.
Somit dürfte es diesen Unterschied nicht geben

PS: Zum Glück nutze ich schon ewig meine KeinUmlaut() Funktion, die alle Umlaute und andere Sonderzeichen umsetzt, das funktioniert immer

[Werner_Bayern]

... und schon bei Alaska gemeldet! ...

Danke an alle! Wem schicke ich jetzt die Flasche Bio-Rotwein?

[Werner_Bayern]

Ich denke, das ist ein klarer PDR !

Hab ich jetzt was gewonnen?

[UliTs]

Wem schicke ich jetzt die Flasche Bio-Rotwein?

Die bringst Du zur DevCon zurück

Uli

[Werner_Bayern]

Du meinst mit? Die muss dann aber auf einem Zimmer gedrunken werden wir können doch da nicht...
Oder meinst Du zwischendurch währen der Vorträge

[UliTs]

Ja, ich meinte mit
Vielleicht in der Sauna ?

Uli