Textfeld in Array umwandeln?!

[Christof]

Hallo,

ich bin mir sicher, dass ich eine solche Funktion schon mal gesehen habe. Aber wo?

Ich möchte z.B. den String "23,514,99915,Schmitz" in ein Array {23,514,99915,"Schmitz"} umwandeln? Mir wäre auch schon weiter geholfen, wenn man im Ergebnis nur Zahlen oder nur Strings im Array hätte.

Bitte, bitte Hilfe. Ich möcht's nicht selbst schreiben...

Merci, danke und thank you

Christof

[Martin Altmann]

Hallo Christof,
Du musst erstmal Deinen String richtig aufbauen - und zwar folgendermassen:

Code: Alles auswählen

cArray := "23,514,99915,Schmitz"
cArray := "{" + cArray + "}"
cArray := strtran( cArray, ",", "," + chr( 34 ), 3 )
cArray := strtran( cArray, "}", chr( 34 ) + "}" )
aArray := &cArray

Sollte gehen - zumindest für eine Zeile. Bei mehreren musst Du halt entsprechend zeilenweise vorgehen.

Viele Grüße,
Martin

[Lewi]

Hi,
nachfolgend eine Funktion, die einen übergebenen String in ein Array umwandel:

Code: Alles auswählen

/************************************
* Str2Array( <cStr>, [cDelim] )
Beispiel: Str2Array( cStr, ";" )
************************************/
FUNCTION  Str2Array(cString, cDelim )
	LOCAL aRet    := {}
	Local nX	 := 1
	Local nPos	:= 0
	LOCAL nLen
	LOCAL cRet

   cDelim := IIF( cDlim == NIL, ";", cDelim)
	if Valtype( cString) <> "C"
		RETURN aRet
	endif

	nLen := LEN( cString )
	cRet := SPACE(nLen)


	WHILE ( .T. )
		nPos := AT(cDelim, cString, nX)

		IF nPos > 0
			cRet 	:= SubStr(cString, nX, nPos-nX)
			AADD(aRet, cRet)
			nX 	:= ++nPos

		ELSEIF nX <= nLen
			cRet 	:= SubStr(cString, nX)
			aadd(aRet, cRet)
			exit

		ELSEIF nX > nLen
			aadd(aRet, "")
			exit
		ELSE
			exit
		ENDIF
	ENDDO

RETURN ( aRet )

Gruß, Olaf

[Christof]

Hab' beides getestet. Funktioniert. DANKE.

Habe mich jetzt für die etwas aufwendigere Methode, dafür steuerbare Methode von Olaf entschieden.


Gruß

Christof