Mauszeiger -> Sanduhr

[satmax]

Hallo,

ich bekomme das mit der Sanduhr nicht hin. Einzig wenn die Maus über der Titelleiste ist wird die Eieruhr angezeigt.

Das Fenster wird in einem eigenen Thread ausgeführt, innerhalb dieses Threads rufe ich folgende Funktion auf:

Code: Alles auswählen

STATIC FUNCTION neueSuche(oDlg)
LOCAL nTreffer:=0

oDlg:drawingarea:SetPointer(nil,XBPSTATIC_SYSICON_WAIT, XBPWINDOW_POINTERTYPE_SYSPOINTER )
oDlg:setPointer(nil,XBPSTATIC_SYSICON_WAIT, XBPWINDOW_POINTERTYPE_SYSPOINTER)

// Some code: 2-3 seconds

oDlg:drawingarea:SetPointer(nil,0,XBPWINDOW_POINTERTYPE_SYSPOINTER )
oDlg:SetPointer(nil,0, XBPWINDOW_POINTERTYPE_SYSPOINTER )

RETURN nil

Was mach ich hier falsch?

Gruß
Markus

[satmax]

Kleiner Nachtrag: die Sanduhr wird angezeigt, nur wenn man die Maus bewegt (auch wenn nur innerhalb des Dialoges) wird sofort ein normaler Cursor daraus.

[Magic]

Einzig wenn die Maus über der Titelleiste ist wird die Eieruhr angezeigt.

Ist richtig so. Du muss (so mache ich es) den Mauszeiger für alle XbaseParts ändern.
Ich mache es folgedermaßen (als self Parameter übergebe ich i.d.R. den aktuellen Dialog):

Code: Alles auswählen

   // Sanduhr als Mauszeiger anzeigen
   ::_setPointer( self, .F. )

Code: Alles auswählen

********************************************************************************
METHOD MAINDIALOG:_setPointer( pxXbasePart, plDefault )
 * Mauszeiger verändern
 * Parameter: pxXbasePart: XbasePArt dessen Mauszeiger verändert werden soll
 *            plDefault: Defaultmauszeiger, sonst Sanduhr
 * Return: NIL
********************************************************************************

   LOCAL aChildList  := pxXbasePart:childList(), ;
         nLen        := 0, ;
         i           := 0

      IF plDefault
         IF .NOT. ( "Button" $ pxXbasePart:className() )
            pxXbasePart:setPointer( , XBPSTATIC_SYSICON_DEFAULT, XBPWINDOW_POINTERTYPE_SYSPOINTER )
         ELSE
            pxXbasePart:setPointer( , ICON_HAND, XBPWINDOW_POINTERTYPE_ICON )
         ENDIF
      ELSE
         pxXbasePart:setPointer( , XBPSTATIC_SYSICON_WAIT, XBPWINDOW_POINTERTYPE_SYSPOINTER )
      ENDIF

      nLen := Len( aChildList )
      FOR i := 1 TO nLen
         ::_setPointer( aChildList[i], plDefault )
      NEXT

RETURN NIL

und zurück

Code: Alles auswählen

   // Mauszeiger default wieder setzen
   ::_setPointer( self, .T. )

[satmax]

Hallo Magic,

super, funktioniert einwandfrei!

Danke
Markus

[brandelh]

Wenn man die Anwendung vor "Störungen" blockieren will, kann man neben disable (was nicht immer erwünscht ist) auch einfach ein durchsichtiges Static control erstellen und so groß wie die Anwendung (Anwendungsmodal oder mit eigener Eventloop) anzeigen. Dieses schluckt dann alle Eingaben