DCPUSHBUTTON ACTION

[Manfred]

Hi,

ich habe das hier gebaut und möchte es mit dem Pushbutton Ende verlassen. Es kommt aber die Fehlermeldung Parameter hat falschen Typ DC-PUSHBUTTON:ACTION(555).
Wie komme ich wieder auf den rechten Pfad der Tugend zurück?

Code: Alles auswählen

METHOD ftasten:paketpreise() // F4 Taste
       LOCAL getlist    := {}
       LOCAL GetOptions
       LOCAL nPBAbstand := 10
       LOCAL nPBBreite  := 60
       LOCAL nPBHoehe   := 20
       LOCAL nPbLinks   := 10
       LOCAL nPBUnten   := 260

       LOCAL oBrowse := NIL
       LOCAL oDialog := NIL

       MEMVAR oMessage
       MEMVAR oZubehoer
       MEMVAR oZubehoerVkPreise

       IF ! oZubehoer:lGefunden
          oMessage:anzeigen("Warenzugang hier nicht möglich")
          RETURN(.F.)
       ENDIF
       (oZubehoerVkPreise:nArea)->(DbSetScope(SCOPE_BOTH,Str(oZubehoer:id,8,0)))
       DCGETOPTIONS NOMINBUTTON;
                    NOMAXBUTTON;
                    AUTORESIZE

       @ nPBUnten,nPBLInks DCPUSHBUTTON;
                                CAPTION "Neu";
                                   SIZE nPBBreite,nPBHoehe;
                                  PIXEL;
                                TOOLTIP "Neuen Preis erfassen"
       nPBLinks += nPBBreite + nPBAbstand
       @ nPBUnten,nPBLInks DCPUSHBUTTON;
                                CAPTION "Ändern";
                                   SIZE nPBBreite,nPBHoehe;
                                  PIXEL;
                                TOOLTIP "unterlegten Preis ändern"
       nPBLinks += nPBBreite + nPBAbstand
       @ nPBUnten,nPBlinks DCPUSHBUTTON;
                                CAPTION "Löschen";
                                   SIZE nPBBreite,nPBHoehe;
                                  PIXEL;
                                TOOLTIP "unterlegten Preis löschen"
       nPBLinks += nPBBreite + nPBAbstand
       @ nPBUnten,nPBlinks DCPUSHBUTTON;
                                CAPTION "Ende";
                                   SIZE nPBBreite,nPBHoehe;
                                 ACTION { || oDialog:destroy() };
                                  PIXEL;
                                TOOLTIP "Menue beenden ohne Speichern"

       @ 1,1 DCBROWSE oBrowse;
                         DATA oZubehoerVkPreise:cAlias;
                         SIZE (nPBLinks + nPBBreite + 10),240;
                   CURSORMODE XBPBRW_CURSOR_ROW;
                         PIXEL;
                        Parent oDialog;
                     HEADLINES 2

       DCBROWSECOL FIELD (oZubehoerVkPreise:nArea)->preissoll;
                   WIDTH 5;
                   HEADER "Preis des;Pakets";
                   PARENT oBrowse;
                   TOOLTIP "Paketpreis"
       DCBROWSECOL FIELD (oZubehoerVkPreise:nArea)->menge;
                   WIDTH 5;
                   HEADER "Menge für;den Preis";
                   PARENT oBrowse;
                   TOOLTIP "Paketmenge"
       DCBROWSECOL FIELD (oZubehoerVkPreise:nArea)->datumvon;
                   WIDTH 5;
                   HEADER "gültig ab;leer=sofort";
                   PARENT oBrowse;
                   TOOLTIP "Gültigkeit ab dem Datum (leer sofort)"
       DCBROWSECOL FIELD (oZubehoerVkPreise:nArea)->datumbis;
                   WIDTH 5;
                   HEADER "gültig bis;leer=immer";
                   PARENT oBrowse;
                   TOOLTIP "Gültigkeit bis zum Datum (leer immer)"

       DCREAD GUI TITLE "Verkaufspreise Zubehör";
                  OWNER SetAppWindow();
                    FIT;
                OPTIONS GetOptions
       (oZubehoerVkPreise:nArea)->(DbClearScope())
RETURN self

[Wolfgang Ciriack]

Hallo Manfred,
versuchs mal mit

Code: Alles auswählen

ACTION {|| DC_ReadGuiEvent(DCGUI_EXIT_ABORT,GetList) }

[Manfred]

Hi Wolfgang,

das scheint zu klappen. Aber warum klappt meine Sache nicht? Ist das Express++ abhängig, oder generell ein Fehlgedanke?

[Tom]

@Manfred: Wenn Du den Dialog zerstörst, ist er nicht mehr da, und was anderes tust Du nicht in diesem Action-Codeblock. Der Eventhandler geht immer noch davon aus, dass GetList und Dialog und alle Elemente vorhanden wären, aber Du ziehst ihm quasi die Füße weg.

Edit: Der von Wolfgang vorgeschlagene Weg ist der generell richtige. DC_ReadGuiEvent() kann mit dem (wie hier genannt) Parameter DCGUI_EXIT_ABORT aufgerufen werden, was bewirkt, dass die interne Abbruchvariable (zu setzen mit TO lMeineAbbruchVariable in DCREAD) auf .F. gesetzt und ggf. innerhalb des Dialogs vorgenommene Änderungen widerrufen (!) werden, wohingegen DCGUI_EXIT_OK die Variable auf .T. setzt und davon ausgeht, dass alles in Ordnung ist. Wenn Du in einem Dialog einfach Objekte zerstörst, in der Hoffnung, mit dem Verschwinden des Fensters wäre auch alles andere weg, machst Du einen grundsätzlichen konzeptionellen Fehler. So würde man auch nicht mit einem eigenen Eventhandler arbeiten!

[Manfred]

Aha,

habe ich jetzt zwar nicht so ganz verstanden, aber trotzdem Danke....
Ich mache doch sonst auch nichts anderes. Rufe über den Button eine Funktion auf, die evtl. DB schließt und dann ::destroy().
Alles recht merkwürdig.

[Tom]

Ich mache doch sonst auch nichts anderes.

Schlecht. Du solltest dann wenigstens noch die Funktion/Prozedur beenden, in der sich dieser Button befindet. Das macht man üblicherweise, indem man in seiner eigenen Eventroutine eine Variable abfragt oder - einfacher - das CLOSE-Event generiert (und dann zerstört man auch erst anschließend die Objekte). Wenn Du einfach nur ein Dialogobjekt zerstörst, mag das dazu führen, dass der Dialog verschwindet, aber Deine Routine hängt dann eben in einem toten Dialog. Dieses DC_ReadGuiEvent beendet den GUI-Reader (also die Eventschleife von eXpress++), wobei eben abhängig vom Parameter auch noch eine Abschlussvariable gesetzt wird, danach zerstört es alle Objekte. Genau so muss man arbeiten.

[Wolfgang Ciriack]

Hallo Manfred,
das ist so, als wenn du beim Autofahren abbremst, schon mal das Auto ausmachst und aussteigst, weil du ja in 10m sowieso anhalten wolltest. Aber Spaß beiseite.
Tom hat das wunderbar erklärt, hier noch einmal der generelle Ablauf.

Code: Alles auswählen

local Getlist:={}, GetOptions, lExitstate

DCGET OPTIONS ....
@...,... DCGET ....
......

@...,... DCPUSHBUTTON CAPTION "Ok"  SIZE..... ;
      ACTION {|| DC_ReadGuiEvent(DCGUI_EXIT_OK,GetList) } ....

@...,... DCPUSHBUTTON CAPTION "Abbruch"  SIZE..... ;
      ACTION {|| DC_ReadGuiEvent(DCGUI_EXIT_ABORT,GetList) } ....

DCREAD GUI ;
   TO lExitState ;
   TITLE .....

if lExitState
  ** Hier landest du, wenn du den Eventhandler deines Dialogs mit ..._OK beendest
else
  ** Hier landest du, wenn du den Eventhandler deines Dialogs mit ..._ABORT beendest
endif
return

[Tom]

Die von Wolfgang genutzte Variable würde auch gesetzt werden, wenn man DCREAD GUI ... (TO lExitState) ... ADDBUTTONS benutzen würde, was ja einen OK- und einen Abbruch-Button automatisch an den Dialog hängt - die beide genau das tun, was die von Wolfgang manuell erzeugten Buttons machen. Sie wird außerdem bei Betätigung des Close-Buttons in der Kopfzeile des Fensters auf .F. gesetzt.

[Manfred]

Moin,

ich schätze ich habe da etwas voreilig geschossen.
So sieht es aus, wenn der Beenden Button gedrückt wird.

Code: Alles auswählen

METHOD Phnsys_vt:beendenButton(oMenu, oThread)
       MEMVAR oPhnsys

       pruefAenderungen(oPhnsys,self)                                           // immer erst nachsehen, ob etwas geändert wurde
       oPhnSys:schliesse_Datenbank(.T.)                                         // alle Datenbanken werden geschlossen, die nicht mehr benötigt werden
       ::oDialog:destroy()                                                      // muß hier rein, weil sonst das Fenster nicht verschwindet
       oMenu:enableItem(::nMenuePunkt)                                          // Menuepunkt für diesen Bereich im Hauptfenster wird wieder aktiviert
       oThread:quit()
RETURN

Da alle Objekte über eigene Methoden :created und :destroyed werden, ist bei ::oDialog:destroy() doch gewährleistet, das auch automatisch alles mit verschwinden sollte. Schließlich ist oDialog der Parent. Und wenn der :destroy() wird, dann geht lt. Debugger alles andere mit in die Kiste. Oder genügt das nicht? Dann müßte ich alles nochmals überdenken. oThread:quit(), sollte hier jetzt nicht besprochen werden, weil das ja sicherlich für den Rest sorgt.

[Manfred]

Hm,

jetzt habe ich es erst richtig gelesen, was Wolfgang geschrieben hat.
Reicht es also nicht, im Action Codeblock die Sache mit

Code: Alles auswählen

ACTION {|| DC_ReadGuiEvent(DCGUI_EXIT_ABORT,GetList) }

zu bauen. Muß ich auf jeden Fall noch die Var lExitState in DCREAD einbauen, oder rundet das nur die Sache ab?

[Tom]

Hallo, Manfred.

Mit dem DC_ReadGuiEvent() läuft Deine Funktion/Prozedure hinter DCREAD weiter. Mit anderen Worten: Es wird dann der Code abgearbeitet, der dem DCREAD folgt - denn bis zu diesem Zeitpunkt hängt der Programmteil in der Eventschleife. Wenn Du danach noch irgendwie darauf reagieren willst, ob abgebrochen oder OK gedrückt wurde, musst die die Variable setzen. Wenn das nicht nötig ist, dann nicht, wenn also z.B. direkt auf das DCREAD ein RETURN folgt und nichts weiter. Aber Achtung: _ABORT und _OK haben auch qualitative Unterschiede! Wenn _ABORT genutzt wird, dann geschieht laut eXpress++-Doku (und auch in der Realität) das hier:

restore all referenced memvar to their original value

[Manfred]

Aha,

jetzt wird es heller. Da in meinem Fall nach dem DCREADGUI die Methode beendet, der Dialog Local ist, wird alles zerstört. Besser wäre aber dann, ich würde in der Regel danach alles machen, was noch gemacht werden müßte, wenn es weitergehen würde.
Ich denke mal, das habe ich verinnerlicht.

Sorry, wenn ich hier so Fragen stelle, aber im Moment weiß ich vor Parameter und Optionen in express++ überhaupt nicht, was ich wo zuerst lesen soll. Ich arbeite also: learning by doing.

Das ist auch das, was ich irgendwann mal meinte, dass Tools zwar schön sind, aber sie sind auch gefährlich, weil man nicht so recht weiß, was wann und wo geschieht. Und den Quelltext durchackern......

[Manfred]

Noch einer,

ich habe aus Neugier hinter DCREADGUI und dem Clear Scope ein Altd() eingebaut. Dann habe ich mir an der Stelle im Debugger angesehen, was bis dahin passiert ist. Was ist denn mit dem oDialog passiert? Das gibt es an der Stelle nicht mehr. Wann wird das denn zerstört?

[Tom]

Der GUI-Reader von eXpress++ zerstört alle referenzierten Objekte, wenn er beendet wird. Es gibt aber Optionen, um ihn daran zu hindern, z.B. "SAVE" oder "NODESTROY".

[Manfred]

Ich sag ja,

ich weiß nicht wo ich anfangen soll zu lesen. Too many fingers on the keyboard....

[Manfred]

Noch etwas, was ich nicht verstehe.

Code: Alles auswählen

PROCEDURE tagesumsatz()
          LOCAL aButton    := {}
          LOCAL getlist    := {}
          LOCAL GetOptions
          LOCAL lDaten     := .F.
          LOCAL nLinks     := 5
          LOCAL nMitte

          LOCAL oDialogEingabe := NIL
          LOCAL oDialogAnzeige := NIL
          LOCAL oText          := NIL

          MEMVAR oHauptDialog

          aButton := {;
                      {"~Suchen",80,30,{|| erstelleTagesumsatz(@lDaten) } },;
                      {"~Ende"  ,80,30,{|| DC_ReadGuiEvent(DCGUI_EXIT_ABORT,Getlist) } };
                     }

          nMitte := oHauptDialog:currentsize()[1]/2-nLinks

          @ 5,nLinks DCSTATIC;
                  OBJECT oDialogEingabe;
                    SIZE nMitte,oHauptDialog:currentsize()[2]-60;
                    TYPE XBPSTATIC_TYPE_RECESSEDRECT
          @ 0,nMitte DCSTATIC;
                  OBJECT oDialogAnzeige;
                RELATIVE oDialogEingabe;
                    SIZE nMitte-13,oHauptDialog:currentsize()[2]-60;
                    TYPE XBPSTATIC_TYPE_RECESSEDBOX

          @ 30, 5 DCSAY "Datum:";
                   FONT "16.Arial";
                 OBJECT oText;
                 PARENT oDialogEingabe;
                   SIZE 0
//------------------------------------------------------------------------------
               DCGETOPTIONS;
                    BUTTONS aButton;
                    MINSIZE -1,-1;
                NOMINBUTTON;
                NOMAXBUTTON;
                      PIXEL;
                 SAYOPTIONS XBPSTATIC_TEXT_VCENTER+XBPSTATIC_TEXT_RIGHT
          DCREAD GUI;
             OPTIONS GetOptions;
              PARENT oHauptDialog
          RETURN
********************************************************************************
FUNCTION erstelleTagesumsatz(lDaten)
         RETURN(.T.)

Wenn ich den Ende Button drücke scheint nichts zu passieren. Ich dachte es würden die Statics und Say destroyed und verschwinden!? Dem ist aber nicht so

[Tom]

Hallo, Manfred.

1. Mach mal bei DCREAD GUI ... PARENT oHauptDialog aus dem PARENT oHauptDialog ein PARENT @oHauptDialog.

2. Was geschieht, wenn den Codeblock für den Ende-Button so veränderst:

Code: Alles auswählen

{|| MsgBox('ENDE!'), DC_ReadGuiEvent(DCGUI_EXIT_ABORT,Getlist) }

[Manfred]

Also es liegt auf jeden Fall an dem Parent oHauptDialog. Aber so kann ich schön den neuen Dialog in den Hauptdialog einbetten. Von der Optik her. Ich habe nun den oHauptdialog entfernt und jetzt klappt es. Aber ich muß jetzt jonglieren, bis die neue Maske in den freien Bildschirm vom Hauptdialog passt.

Oops, Tom du warst schneller.

Werde ich mal probieren

[Manfred]

Hi Tom,

hat beides nichts gebracht. Aber wie schön einen höher erwähnt, ich mache es dann so. Das klappt. War zwar etwas Schiebearbeite, aber das paßt schon.
Danke trotzdem.