XbpBrowse refreshen [Erledigt]

[Jan]

Hallo,

ich arbeite gerade an einem XbpBrowse, der regelmäßig refresht werden soll. Damit die angezeigten Daten aus einer im Hintergrund fortlaufend aktualisierten dbf immer aktuell auf dem Bildschirm erscheinen. Ich habe da mal zwei Varianten versucht.

1) Den Refresh in die Event-Schleife gelegt, verbunden mit einer Verzögerung von 0,1 Sekunden. Mir war dabei etwas unwohl, weil ich die Eventschleife dafür nicht mißbrauchen wollte. Leider funktionierte das auch nur, wenn man mit der Maus über den Browse fuhr. Dann wurde wirklich refreshed. Also wohl nicht so der ganz gute Weg.

2) Mal ganz brachial diese Zeile eingefügt:

Code: Alles auswählen

oBrowse:stableBlock := {|| SetAppFocus(oBrowse), Inkey(1), oBrowse:refreshAll()}  

Das funktioniert wirklich. Flackert zwar bei jedem Refresh, aber man kann ja nicht alles haben ... Aber der große Nachteil ist: Nach wenigen Minuten stürzt das gesamte Programm kommentarlos ab. Als ob da irgendwas überlaufen würde.

Wie macht Ihr das? Was wäre der eleganteste Weg, sowas zu erledigen?

Jan

[brandelh]

Die normale Eventloop wartet ja bis ein Ereignis eintritt, also wird auch nichts refreshed, wenn nichts passiert (Maus, Keyboard etc.)
Die eleganteste Lösung dürfte ein eigenen Thread sein, regelmäßig die Daten anzeigt, aber 0,1 Sekunden also 10x je Sekunde ist viel zu oft
Wenn du die Funktion SetTimerEvent() nicht schon benutzt, könntest du das einrichtigen.

Im dortigen Beispiel wird alle Sekunde die Uhrzeit angezeigt:

SetTimerEvent(100, {|| DispOutAt(0, 0, Time()) } )

Ich würde eine Methode des Fensters machen, die sich um die Daten (DBF Refreshall) und die Anzeige kümmert und diese im Event aufrufen:

SetTimerEvent(100, {|| ::RefreshBrowser() } )

ich habe es jetzt nicht getestet, aber das sollte so gehen, wenn nicht, einfach einen eigenen Thread eröffnen ...

[brandelh]

PS: inkey(1) in einer GUI Anwendung ?

[Jan]

PS: inkey(1) in einer GUI Anwendung ?

Naja, es geht halt. Auch wenn das ansich irgendwie nicht zusammen passen sollte.

Jan

[Jan]

Hallo Hubert,

hmm, SetTimerEvent() ist sicher mal wert angesehen zu werden. Hab ich glaube ich bislang nicht benutzt.

Aber ob daß das Richtige ist? Ich will ja nicht alle paar Sekunden den Browse neu aufbauen. Das wäre dann wohl doch zu viel Overhead. Ich will den einfach nur aktualisieren.

Oder versteh ich Dich da miß?

Und klar, Inkey(.1) war auch falsch. Ich hab den wirklich auf 1 stehen. Solange ich da noch rum teste. Später im scharfen Betrieb soll die Verzögerung dann bei 5 oder sogar 10 Sekunden liegen.

Jan

[brandelh]

Hallo Jan,

Ich denke, du möchtest jede Sekunde die Daten neu anfordern und dann die Anzeige refreshen und NICHT das XbpBrose() Objekt neu erzeugen ...
Wenn das richtig ist, dann ist SetTimerEvent() ein guter Weg, wobei man könnte dort auch einen PostAppEvent hinterlegen ... aber egal wie, was muss man tun ?

Code: Alles auswählen

[b]oB:refreshAll()[/b]  ... definiert die Anzeige aller Datenzeilen im Browse-Fenster als ungültig.
[b]oB:forceStable()[/b] ...  Im nächsten Stabilisierungszyklus werden daher die Daten aus der Datenquelle via oXbpColumn:dataLink neu eingelesen und angezeigt. 

Ich würde das maximal alle 5 Sekunden durchführen, je nach Anwender im Netzwerk kann das häufig Refreshen schon ein Problem werden.
In meinen Anwendungen habe ich immer nur nach eigenen Änderungen Refreshed, oder wenn der Anwender das angefordert hat.

PS: ohne oB:refreshAll() macht oB:forceStable() nach meiner Meinung keinen Sinn, wenn die Änderungen nicht auf dem eigenen Rechner erfolgt sind.

[Koverhage]

Ich würde einen Schalter setzen, z.B. lMustRefresh
Wenn der auf Ja steht, refreshall
Dieser Schalter muss bei Änderungen in der db gesetzt werden, und nach dem refresh auf .f.

[brandelh]

Wenn man SELBST die Änderungen macht, reicht auch RefreshCurrent(), wenn aber andere die DBF / SQL Server ändern, dann nützt nichts außer die Daten neu einzulesen.

[Tom]

Originelle Ansätze.

Ich würde das viel simpler lösen. Beim Aufruf der Tabelle wird ein Timestamp mit den Dateidaten generiert, beispielsweise DtoS(FileDate())+FileTime() (Funktionen aus den Tools, aber es gibt auch andere, verlässlichere). In der Eventloop wird alle x Sekunden geprüft, ob die aktuellen Daten neuer sind, dann wird der Timestamp aktualisiert und ein RefreshAll() ausgelöst. Feddisch. Hat den Vorteil, dass es kein unmotiviertes Flackern gibt, obwohl sich nix getan hat, und selbst in ungepatchten SMB2-Netzen beträgt die Latenz höchstens 10+x Sekunden.

Alternativ kann man mit jeder Änderung/Ergänzung auch Nachrichtendateien anlegen oder aktualisieren.

[Jan]

Hallo Hubert, Klaus, und Tom,

da kommen ja wirklich gute Ideen zusammen!

Ich könnte mir vorstellen das mir der Weg von Tom am Besten gefallen würde. Ich werde das mal durchtesten.

Wobei allerdings die Frage offen bleibt, warum das ganze Programm nach einigen Minuten sich einfach verabschiedet. Was es nicht macht wenn ich den Refresh weg lasse.

Jan

[Tom]

Wobei allerdings die Frage offen bleibt, warum das ganze Programm nach einigen Minuten sich einfach verabschiedet.

Du meinst, mit Deiner oBrowse:stableBlock-Lösung? Nunwohl. Der Slot wird ausgewertet, wenn das Browse stabilisiert wurde. Da im Block ein RefreshAll() ausgelöst wird, was in aller Regel wiederum eine Stabilisierung nach sich zieht, wirst Du ganz simpel in einem Stack Overflow landen - und/oder in einer Endlosrekursion. Das ist, wie Du selbst erklärst, tatsächlich recht brachial, und es wundert mich, dass es überhaupt für ein paar Minuten funktioniert.

[Jan]

Tom,

leider hat Deine Lösung ein kleines Problem: Ein Event wird nur ausgelöst, wenn da auch was passiert. Wenn der Browse aber einfach nur still und leise auf dem Monitor steht, niemand da eine Maus drüber schubst oder ähnliches macht, dann läuft der nicht in die Event-Schleife rein.

Jan

[Werner_Bayern]

Event-Schleife <nTimeOut> ändern!

[Tom]

Oder in der Eventschleife machen, aber außerhalb der Eventauswertung.

[Jan]

Hallo Tom,

so hab ich das im Moment eingebaut:

Code: Alles auswählen

DO WHILE .T.
   nEvent := AppEvent(@mp1, @mp2, @oXbp)
   oXbp:handleEvent(nEvent, mp1, mp2)

   aDirectory := Directory(pfadExe() + pfadDaten() + "knx.dbf")
   IF .NOT. aDirectory[1][F_WRITE_TIME]== cAktuelleZeit
      oBrowse:refreshAll()
      cAktuelleZeit := aDirectory[1][F_WRITE_TIME]
   ENDIF

ENDDO

Was soll ich daran ändern???

Ich hatte übrigens eben noch ein Problem: Der hat so oder so nicht refreshed. Weil die Datei-Zeit immer gleich geblieben ist. Egal was ich da rein geschrieben habe, die änderte sich nicht. Erst nachdem ich ein DbCommit() eingebaut habe, habe ich unter Windows wirklich das letzte Schreibdatum drin. Böse Falle!

Jan

[Tom]

Hallo, Jan.

Ein DbSkip(0) nach dem Schreiben oder Löschen hat ähnliche Effekte.

Ich würde um das ständige Auslesen der Dateidaten herum noch einen Timer setzen; in Deiner vorliegenden Konstruktion wird es andauernd ausgelöst. Du kannst auch mit SetTimerEvent() in eine Funktion verzweigen, die das übernimmt. Und Du musst wahrscheinlich früher oder später darauf achten, dass ein Refresh des Browses natürlich nicht ausgelöst werden darf, wenn im aktuellen Dialog gerade etwas damit geschieht, z.B. eine Bearbeitung stattfindet. Vorausgesetzt, es gibt eine solche Funktionalität.

[brandelh]

Deine Schleife arbeitet wieder nur nach Events, du wolltest das aber anders

Code: Alles auswählen

nNextRefresh := 0
cFile := pfadExe() + pfadDaten() + "knx.dbf" // bleibt gleich, also auslagern
DO WHILE .T.
   nEvent := AppEvent(@mp1, @mp2, @oXbp, 100 )  // spätestens 1 Sekunde beenden
   if nEvent # xbe_None
      oXbp:handleEvent(nEvent, mp1, mp2)
   endif // *** das hier war vorher ganz unten.
   if nNextRefresh < seconds()
      nNextRefresh := seconds() + 5 // alle 5 Sekunden
      aDirectory := Directory(cFile)
      // wenn das mal gut geht, bei den aktuellen Metadaten ... und bei SQL ?
      IF .NOT. aDirectory[1][F_WRITE_TIME]== cAktuelleZeit
         oBrowse:refreshAll()
         cAktuelleZeit := aDirectory[1][F_WRITE_TIME]
      ENDIF
   endif 
ENDDO

Anmerkung, hier wird ohne Event auch nicht refreshed, TOM hat es unten verbessert ...
PS: besser ich verbessere es gleich selbst auch hier !

[Werner_Bayern]

nEvent := AppEvent(@mp1, @mp2, @oXbp)

Wartet solange, bis ein Ereignis eintritt. Verwendest Du den 4. Parameter <nTimeOut>, hast Du nicht das von Dir beschriebene Problem, dass die Maus bewegt werden muss.

[Tom]

Hallo, Hubert.

Deine Schleife arbeitet wieder nur nach Events, du wolltest das aber anders

In Deinem Code aber erst recht. Edit: Quatsch. Ich hatte den Parameter bei AppEvent übersehen. Schulljung.

Außerdem stimmt das nicht. Jan hatte das gleich am Anfang hinter das "DO WHILE .T." gesetzt, wodurch es ganz unabhängig von eingehenden Events eigentlich pausenlos ausgeführt werden müsste.

[Tom]

Wartet solange, bis ein Ereignis eintritt.

Stimmt. Also entweder den Timeout-Parameter verwenden oder mit SetTimerEvent auslagern.

[Tom]

Huberts Vorschlag müsste mit einer kleinen Änderung eigentlich gut funktionieren:

Code: Alles auswählen

nNextRefresh := 0
cFile := pfadExe() + pfadDaten() + "knx.dbf" // bleibt gleich, also auslagern
DO WHILE .T.
   nEvent := AppEvent(@mp1, @mp2, @oXbp, 100 )  // spätestens 1 Sekunde beenden
   if nEvent # xbe_None
      oXbp:handleEvent(nEvent, mp1, mp2)
   endif // weil das Refresh sonst bei keinem Event - xbe_None - nie ausgelöst würde
   if nNextRefresh < seconds()
       nNextRefresh := seconds() + 5 // alle 5 Sekunden
       aDirectory := Directory(cFile)
       // wenn das mal gut geht, bei den aktuellen Metadaten ... und bei SQL ?
       IF .NOT. aDirectory[1][F_WRITE_TIME]== cAktuelleZeit
          oBrowse:refreshAll()
          cAktuelleZeit := aDirectory[1][F_WRITE_TIME]
       ENDIF
   endif
ENDDO

[brandelh]

@ TOM

hast Recht, da habe ich mich bei den IF / ENDIF vertan ... das kommt davon wenn man es nicht probiert

[Jan]

Hallo Jungs,

hervorragende Arbeit! Vielen Dank für die Hilfe So funktioniert das einwandfrei.

Jan

[AUGE_OHR]

Code: Alles auswählen

oBrowse:stableBlock := {|| SetAppFocus(oBrowse), Inkey(1), oBrowse:refreshAll()}

in einen o:StableBlock sollte man KEINE weitere "Navigation" Befehle oder self:Methoden ausführen da diese rekursive wieder zum o:StableBlock führen

Code: Alles auswählen

xbe_None

IST ein Event der NUR durch den 4th Parameter von AppEvent ausgelöst wird.

[brandelh]

Code: Alles auswählen

xbe_None

IST ein Event der NUR durch den 4th Parameter von AppEvent ausgelöst wird.

das stimmt nicht.

xbe_None ist der Wert, der von AppEvent zurückgegeben wird, wenn KEIN EVENT sondern ein TIMEOUT (4. Parameter) die Funktion beendet hat