bei unserem gestrigen XUG Treffen kam folgender Vorschlag auf den Tisch
Code: Alles auswählen
METHOD datenbank:felderSchreiben(oQuelle,;
lNeuerSatz,;
oZiel,;
lPruefLeer,;
lSchreiben,;
lSatzLoeschen,;
lFelderleeren,;
lDatenBankDirekt,;
lSatzEntsperren,;
cProcName,;
nPause,;
lSkip,;
lSpeicherMeldung,;
lKeinZwang)
LOCAL bArbeit
LOCAL bSaveError := ErrorBlock( {|e|BREAK(e)})
LOCAL cArbeit
LOCAL cFeld
LOCAL lErfolg := .T.
LOCAL nFcount // darf hier noch nicht belegt werden!!! weil das Zielobjekt hier noch nicht 100% feststeht
LOCAL nI
// LOCAL nOldSelect := Select()
LOCAL oProtokoll := protokolle():new()
LOCAL oError
MEMVAR oId
MEMVAR oSysPara
DEFAULT oQuelle TO self // standardmäßig wird die zugehörige DB benutzt
DEFAULT lNeuerSatz TO .F. // standardmäßig wird kein neuer Satz angehängt
DEFAULT oZiel TO self // standardmäßig wird die zugehörige DB benutzt
DEFAULT lPruefLeer TO .T.
DEFAULT lSchreiben TO .T. // es wird immer ein Commit dahinter gesetzt
DEFAULT lSatzLoeschen TO .F. // Sätze werden normalerweise nicht gelöscht
DEFAULT lFelderleeren TO .F.
DEFAULT lDatenbankDirekt TO .F.
DEFAULT lSatzEntsperren TO .T.
DEFAULT cProcName TO ProcName(1) + "(" + Alltrim(STr(ProcLine(1))) + ")" // dann wird die aufrufende Routine eingetragen nebst zeile
DEFAULT nPause TO 0
DEFAULT lSkip TO .F.
DEFAULT lSpeicherMeldung TO .F.
DEFAULT lKeinZwang TO .F.
::aTempArray := {}
::nTempZaehler := 0
nFcount := (oZiel:nArea)->(Fcount()) // Zielobjekt abfragen, wieviele Felder es gibt
IF lNeuerSatz
IF ! lPruefLeer .OR. ! ::satzRecall(oZiel) // normalerweise wird immer zuerst ein leerer Satz genommen und wieder aktiviert
IF ! ::satzNeu(oZiel,cProcName) // damit kein Fehler entsteht
RETURN(.F.) // erstmal so, später eine elegantere Lösung
ENDIF
ENDIF
ELSE
IF ! ::satzSperren(oZiel,cProcName,nPause,,lKeinZwang) // ich hoffe das genügt ohne viel Heckmeck
lErfolg := .F.
ENDIF
ENDIF
IF lErfolg // baue ich hier mal ein, wenn keine Sperren mögllich war, dann darf das hier auch nicht durchlaufen werden
IF lSatzLoeschen
::felderleeren()
ELSE
IF ! lDatenbankDirekt // ansonsten würde bei größeren Mengen der Zähler nur hochzählen
IF oZiel:nIdSatz > 0 .AND. oZiel:id = 0 // sollte als Zeichen dafür dienen, das auch eine vergeben werden soll
IF ! oId:idSpeichern(oZiel)
oSysPara:oMessage:anzeigen("ACHTUNG, die Satznummer konnte nicht erzeugt/gespeichert werden. Programmabbruch")
AppQuit(,,"ID konnte nicht gespeichert werden")
ELSE
oZiel:id := oId:id
ENDIF
ENDIF
ENDIF
ENDIF
// Dbselectarea(oZiel:nArea) // weil ja auf jeden Fall ins Ziel geschrieben wird
FOR nI := 1 TO nFcount
// cFeld := (Alias())->(FieldName(nI))
cFeld := (oZiel:nArea)->(FieldName(nI))
IF ::lPruefeDbStrukturArrayAus .AND. ! IsMemberVar(self,cFeld,VAR_INSTANCE)
ELSE
IF lDatenbankDirekt
// cArbeit := "{|oQuelle| (Alias())->"+cFeld+" := (oQuelle:nArea)->"+cFeld+"}"
cArbeit := "{|oZiel,oQuelle| (oZiel:nArea)->"+cFeld+" := (oQuelle:nArea)->"+cFeld+"}"
ELSE
// cArbeit := "{|oQuelle| (Alias())->"+cFeld+" := oQuelle:"+cFeld+"}"
cArbeit := "{|oZiel,oQuelle| (oZiel:nArea)->"+cFeld+" := oQuelle:"+cFeld+"}"
ENDIF
bArbeit := &(cArbeit)
AAdd(::aTempArray, bArbeit)
ENDIF
NEXT
DO WHILE .T.
BEGIN SEQUENCE
oProtokoll:nMessStart := Seconds()
AEval(::aTempArray,{ |b,i|::nTempZaehler := i, Eval( b, oQuelle, oZiel ) })
IF ::lZusatzDbfFelder
// (Alias())->usertime := Time() + " - " + DToC(Date())
(oZiel:nArea)->usertime := Time() + " - " + DToC(Date())
ENDIF
oProtokoll:nMessEnde := Seconds()
IF oZiel:nSatzNummer = 0
// oZiel:nSatzNummer := (::nArea)->(Recno())
oZiel:nSatzNummer := (oZiel:nArea)->(Recno())
ENDIF
RECOVER USING oError
altd() // der dient der Fehlersuche
IF oSysPara:oPruefen:fehlerbehandlung(oError,self)
LOOP
ENDIF
lErfolg := .F.
END SEQUENCE
ErrorBlock(bSaveError)
EXIT
ENDDO .T.
ENDIF
IF lErfolg
IF lSatzLoeschen
::satzSperren(oQuelle,cProcName,nPause) // das sollte eigentlich richtig sein.
(oQuelle:nArea)->(DbDelete()) // wenn dann muß doch die Quelle gelöscht werden, die wird doch immer genutzt
ENDIF
IF lSatzEntsperren
::satzEntsperren(oZiel)
ENDIF
IF lSchreiben
IF lSkip
(oZiel:nArea)->(DbSkip(0)) // evtl. mal testen mit DbGoTop() und wieder zurück zum satz. Soll besser klappen lt. Hubert (11.10.2012)
ELSE
(oZiel:nArea)->(Dbcommit()) // es gab Probleme bei DELETED() Sätzen. Es wurde dann verkehrt gesprungen bei Skip(0)
ENDIF
ENDIF
IF lFelderleeren // wenn die Membervars resettet werden sollen
::felderleeren()
ENDIF
IF lSpeicherMeldung
IF ! lSatzLoeschen
oSysPara:oMessage:anzeigen("Satz wurde gespeichert")
ELSE
oSysPara:oMessage:anzeigen("Satz wurde gelöscht")
ENDIF
ENDIF
ENDIF
// DbSelectArea(nOldSelect)
bArbeit := NIL
bSaveError := NIL
cArbeit := NIL
cFeld := NIL
nFcount := NIL
nI := NIL
nOldSelect := NIL
oProtokoll := NIL
oError := NIL
RETURN lErfolg
